BBjStandardGrid

rem ' BBjStandardGrid

print stbl("!COMPAT","LEGACY_FONTS=TRUE")

rem ' Calendar uses localized month and day names:
print stbl("!LOCALE","de_DE")
print stbl("!LOCALE","es_ES")
print stbl("!LOCALE","fr_FR")
print stbl("!LOCALE","it_IT")
print stbl("!LOCALE","nl_NL")
print stbl("!LOCALE","sv_SE")
print stbl("!LOCALE","en_US")

sysgui = unt
open (sysgui)"X0"

sysgui! = bbjapi().getSysGui()
sysgui!.setScale(1.5,1.5)

MonthVector! = sysgui!.makeVector()
DayTable! = new java.util.HashMap()

rem 'Get standard date info from the STRING table
dim DateInfo$:"Mask:C(32*=0),SM[12]:C(3*=0),M[12]:C(32*=0),SD[7]:C(3*=0),D[7]:C(32*=0)"
DateInfo$ = stbl("!DATE")

dateMask$ = DateInfo.Mask$
dateMask$ = "%Ml %Dz %Y"

for x=0 to 6
  Item$ = DateInfo.sd$[x+1]
  DayTable!.put(Item$,x)
next x

DayMask$ = "##B"

CurrentJul = 0
CurrentDate$ = date(CurrentJul:dateMask$)
CurrentMonthYear$ = date(CurrentJul:"%Ml %Y")
CurrentDay = num(date(CurrentJul:"%Dz"))
CurrentMonth = num(date(CurrentJul:"%Mz"))
CurrentYear = num(date(CurrentJul:"%Y"))

window! = sysgui!.addWindow(50,50,250,290,"Calendar",$00090083$)
window!.setCallback(window!.ON_CLOSE,"DoAppClose")

grid! = window!.addGrid(100,10,50,230,190,$8042$,6,7)
grid!.setLineColor(BBjColor.LIGHT_GRAY)
grid!.setFitToGrid(1)
grid!.setSnapToRowHeight(0)
grid!.setColumnHeaderForeColor(BBjColor.BLUE)
grid!.setColumnHeaderAlignment(grid!.GRID_ALIGN_CENTER)
grid!.setMainGridForeColor(BBjColor.BLUE)
grid!.setRowHeight(25)
grid!.setSelectionMode(grid!.GRID_SELECT_CELL)
grid!.setMainGridAlignment(grid!.GRID_ALIGN_RIGHT)
grid!.setColumnHeaderForeColor(BBjColor.BLUE)

for col = 0 to 6
  grid!.setColumnHeaderCellText(col,DateInfo.sd$[col+1])
next col

grid!.setCallback(grid!.ON_GRID_DOUBLE_CLICK,"DoSelectDay")
grid!.setCallback(grid!.ON_GRID_MOUSE_DOWN,"DoHighlightDay")

rem ' https://en.wikipedia.org/wiki/Media_control_symbols

unicode = 0

BackYear! = window!.addMenuButton(101,10,10,35,30,"<<")
if unicode then BackYear!.setText(new String($23ea$,"UTF-16"))
BackYear!.setToolTipText("Previous Year")
BackYear!.setCallback(BackYear!.ON_BUTTON_PUSH,"DoBackYear")

BackMonth! = window!.addMenuButton(102,45,10,30,30,"<")
if unicode then BackMonth!.setText(new String($23f4$,"UTF-16"))
BackMonth!.setToolTipText("Previous Month")
BackMonth!.setCallback(BackMonth!.ON_BUTTON_PUSH,"DoBackMonth")

CurrDate! = window!.addStaticText(103,75,15,100,25,"",$4000$)
CurrDate!.setForeColor(BBjColor.BLUE)

FwdMonth! = window!.addMenuButton(104,175,10,30,30,">")
if unicode then FwdMonth!.setText(new String($23f5$,"UTF-16"))
FwdMonth!.setToolTipText("Next Month")
FwdMonth!.setCallback(FwdMonth!.ON_BUTTON_PUSH,"DoForwardMonth")

FwdYear! = window!.addMenuButton(105,205,10,35,30,">>")
if unicode then FwdYear!.setText(new String($23e9$,"UTF-16"))
FwdYear!.setToolTipText("Next Year")
FwdYear!.setCallback(FwdYear!.ON_BUTTON_PUSH,"DoForwardYear")

CurrentMonth! = window!.addMenuButton(106,10,250,230,30,"Current Month")
CurrentMonth!.setToolTipText("Current Month")
CurrentMonth!.setCallback(CurrentMonth!.ON_BUTTON_PUSH,"DoCurrentMonth")

gosub DoCurrentMonth

process_events

DoAppClose:
  release

DoBackYear:
  CurrentDay = 1
  CurrentYear = CurrentYear-1
  gosub DisplayMonth
return

DoBackMonth:
  CurrentDay = 1
  CurrentMonth = CurrentMonth-1
  if CurrentMonth < 1 then
    CurrentMonth = 12
    CurrentYear = CurrentYear-1
  endif
  gosub DisplayMonth
return

DoCurrentMonth:
  CurrentJul = 0
  CurrentDate$ = date(CurrentJul:dateMask$)
  CurrentMonthYear$ = date(CurrentJul:"%Ml %Y")
  CurrentDay = num(date(CurrentJul:"%Dz"))
  CurrentMonth = num(date(CurrentJul:"%Mz"))
  CurrentYear = num(date(CurrentJul:"%Y"))
  gosub DisplayMonth
  grid!.setSelectedCell(CurrRow,CurrCol)
return

DoForwardMonth:
  CurrentDay = 1
  CurrentMonth = CurrentMonth+1
  if CurrentMonth > 12 then
    CurrentMonth = 1
    CurrentYear = CurrentYear+1
  endif
  gosub DisplayMonth
return

DoForwardYear:
  CurrentDay = 1
  CurrentYear = CurrentYear+1
  gosub DisplayMonth
return

DoSelectDay:
  CurrRow = grid!.getSelectedRow()
  CurrCol = grid!.getSelectedColumn()
  gosub DoCalcCurrJul
  if CurrentJul then
     answer=msgbox("You have selected "+date(CurrentJul:dateMask$))
  endif
return

DoHighlightDay:
  event! = sysgui!.getLastEvent()
  CurrRow = event!.getRow()
  CurrCol = event!.getColumn()
  gosub DoCalcCurrJul
  grid!.setSelectedCell(CurrRow,CurrCol)
return

DisplayMonth:
  DayNum = 0
  FirstDayOfMonth = DayTable!.get(date(jul(CurrentYear,CurrentMonth,1):"%Ds"))
  DaysInMonth = FNDaysInMonth(CurrentYear,CurrentMonth)
  MonthVector!.clear()
  if CurrentDay > DaysInMonth+1 then
    CurrentDay = DaysInMonth+1
  endif
  CurrentJul = jul(CurrentYear,CurrentMonth,CurrentDay)

  rem 'Week 0
  for DayOfWeek=0 to 6
    if FirstDayOfMonth > DayOfWeek then
      Item$ = str(0:DayMask$)
    else
      Item$ = str(DayNum+1:DayMask$)
      DayNum = DayNum+1
    endif
    MonthVector!.addItem(Item$)
  next DayOfWeek

  rem 'Week 1-3
  for Week=1 to 3
    for DayOfWeek=0 to 6
      Item$ = str(DayNum+1:DayMask$)
      DayNum = DayNum+1
      MonthVector!.addItem(Item$)
    next DayOfWeek
  next Week

  rem 'Week 4-5
  for week=4 to 5
    for DayOfWeek=0 to 6
      if DayNum > DaysInMonth then
        Item$ = str(0:DayMask$)
      else
        Item$ = str(DayNum+1:DayMask$)
        DayNum = DayNum+1
      endif
      MonthVector!.addItem(Item$)
    next DayOfWeek
  next week

  rem 'Set the current information
  grid!.clearMainGrid()
  grid!.deselectAllCells()
  grid!.setBackColor(BBjColor.WHITE)
  grid!.setCellText(0,0,MonthVector!)
  CurrRow = int((FirstDayOfMonth+CurrentDay-1)/7)
  CurrCol = mod(FirstDayOfMonth+CurrentDay-1,7)
  CurrentMonthYear$ = date(CurrentJul:"%Ml %Y")
  CurrDate!.setText(CurrentMonthYear$)
return

DoCalcCurrJul:
  CurrentDay=num(grid!.getCellText(CurrRow,CurrCol))
  if CurrentDay > 0 then
    CurrentJul = jul(CurrentYear,CurrentMonth,CurrentDay)
  else
    CurrentJul = 0
  endif
return

def FNDaysInMonth(fYear,fMonth)
  rem 'calculate the number of days in a month - zero based
  DaysInMonth = 30
  if fMonth <> 12 then
    DaysInMonth=num(date(jul(fYear,fMonth+1,1)-1:"%D"))-1
  endif
  return DaysInMonth
fnend