BBjStandardGrid::setCellListControl

Description

Sets a list control for a BBjStandardGrid cell so that the cell will display as a list button when edited.

Syntax

Return Value	Method
void	setCellListControl(int row, int column, BBjListButton list!)
void	setCellListControl(int row, int column, BBjListEdit list!)

Parameters

Variable	Description
row	Specifies the 0-based row.
column	Specifies the 0-based column.
list!	Specifies the BBjListButton or BBjListEdit control object to use.

Return Value

None.

Remarks

Once the list control is set, it will display in the specified grid cell when editing has begun on a cell. This will allow the user to select an item from the list, or type into a list edit if a BBjListEdit is used. When in display mode, the cell will show the selected item. When getCellText() is used on a cell in the column, it will return the text of the selected item. When setCellText(row,col,text) is used, it will temporarily replace the text from the list control. The object can be manipulated using the methods for the BBjListEdit or BBjListButton control. When changing the content of the list, it may be necessary to re-bind the list control to the grid.

Also note that parameter x in the EDITKILL NOTIFY event (code=7) specifies the selected index of the list if the edited cell was a list control. The field will contain the item that the user selected.

When the owner of the parameter does not match the object on which the methods is being called, an !ERROR=208 Multi Thread results. See Accessing Objects From Different Interpreters.

Example

rem 'Set the list control for a cell in a BBjGrid object

rem 'Obtain the instance of the BBjAPI object
let myAPI!=BBjAPI()

rem 'Open the SysGui device
SYSGUI=UNT
OPEN (SYSGUI) "X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui!=myAPI!.getSysGui()

rem 'Create the main window and control objects
GOSUB CreateCalendar

rem 'Display the initial data
GOSUB DisplayMonth

rem 'Set the text for rest of the month starting at the current day
myVector! = myAPI!.makeVector()
FOR I = CurrentDay TO DaysInMonth
    myVector!.addItem(STR(I))
NEXT I
Calendar!.setCellText(CurrRow,CurrCol,myVector!)

rem 'Create and set the cell list control
listButt!=MainWindow!.addListButton(110,0,0,100,25,$$)
listButt!.addItem("1")
listButt!.addItem("2")
listButt!.addItem("3")
listButt!.selectIndex(1)
calendar!.setCellListControl(0,0,listButt!)

rem 'Display the main window
MainWindow!.setVisible(mySysGui!.TRUE)

rem 'Register the CALLBACK routines
CALLBACK(ON_CLOSE,DoAppClose,CalendarContext)

rem 'Process Events
process_events

rem 'Callback routine called when the user closes the application window
DoAppClose:
release
return

rem 'Subroutine called to display the days in the current selected month/year
DisplayMonth:
    let DayNum=0
    let FirstDayOfMonth=DayTable!.get(DATE(JUL(CurrentYear,CurrentMonth,1):"%Ds"))
    let DaysInMonth=FNDaysInMonth(CurrentYear,CurrentMonth)
    MonthVector!.clear()
    if (CurrentDay>DaysInMonth+1) then
        CurrentDay=DaysInMonth+1
    endif
    let CurrentJul=JUL(CurrentYear,CurrentMonth,CurrentDay)

    rem 'Week 0
    FOR DayOfWeek=0 TO 6
        if (FirstDayOfMonth>DayOfWeek) then
            let Item$=STR(0:DayMask$)
        else
            let Item$=STR(DayNum+1:DayMask$)
            let DayNum=DayNum+1
        endif
        MonthVector!.addItem(Item$)
    NEXT DayOfWeek

    rem 'Week 1-3
    FOR Week=1 TO 3
        FOR DayOfWeek=0 TO 6
            let Item$=STR(DayNum+1:DayMask$)
            let DayNum=DayNum+1
            MonthVector!.addItem(Item$)
        NEXT DayOfWeek
    NEXT Week

    rem 'Week 4-5
    FOR week=4 TO 5
        FOR DayOfWeek=0 TO 6
            if (DayNum>DaysInMonth) then
                let Item$=STR(0:DayMask$)
            else
                let Item$=STR(DayNum+1:DayMask$)
                let DayNum=DayNum+1
            endif
            MonthVector!.addItem(Item$)
        NEXT DayOfWeek
    NEXT week

    rem 'Set the current information
    Calendar!.setCellText(MonthVector!)
    let CurrRow=INT((FirstDayOfMonth+CurrentDay-1)/7)
    let CurrCol=MOD(FirstDayOfMonth+CurrentDay-1,7)
    Calendar!.setSelectedCell(CurrRow,CurrCol)
    let CurrentMonthYear$=DATE(CurrentJul:"%Ml %Y")
    CurrDate!.setText(CurrentMonthYear$)
    Calendar!.setCellText(5,5," To")
    Calendar!.setCellText(5,6,"day ")
return

rem 'Function called to return the number of days in the passed year and month
DEF FNDaysInMonth(fYear,fMonth)

rem 'calculate the number of days in a month - zero based
let DaysInMonth=30
if (fMonth<>12) then
    let DaysInMonth=NUM(DATE(JUL(fYear,fMonth+1,1)-1:"%D"))-1
endif
return DaysInMonth
FNEND

rem 'Subroutine called to create the calendar
CreateCalendar:
    rem 'Create the vector to hold month info
    let MonthVector!=mySysGui!.makeVector()

    rem 'Create a java hash table to hold day names
    let DayTable!=new java.util.Hashtable()

    rem 'Get standard date info from the STRING table
    DIM DateInfo$:"Mask:C(32*=0),SM[12]:C(3*=0),M[12]:C(32*=0),SD[7]:C(3*=0),D[7]:C(32*=0)"
    let DateInfo$=STBL("!DATE")

    rem 'Build the masks for the dates
    let dateMask$=DateInfo.Mask$
    let M=POS("%M"=dateMask$),dateMask$=dateMask$(1,M+1)+"l"+dateMask$(M+3)
    let M=POS("%Y"=dateMask$),dateMask$=dateMask$(1,M+1)+dateMask$(M+3)
    while POS("/"=dateMask$)
        let M=POS("/"=dateMask$),dateMask$(M,1)=" "
    wend

    rem 'Build the day table
    FOR X=0 TO 6
        let Item$=DateInfo.SD$[x+1]
        DayTable!.put(Item$,x)
    NEXT X

    rem 'Get current date info
    let CurrentDate$=DATE(CurrentJul:dateMask$)
    let CurrentMonthYear$=DATE(CurrentJul:"%Ml %Y")
    let CurrentDay=NUM(DATE(CurrentJul:"%Dz"))
    let CurrentMonth=NUM(DATE(CurrentJul:"%Mz"))
    let CurrentYear=NUM(DATE(CurrentJul:"%Y"))

    rem 'Misc
    let TITLE$="BBjGrid"
    let DayMask$="##B"
    let CurrentJul=0,CalX=400,CalY=400

    rem 'Get the next available context
    let CalendarContext=mySysGui!.getAvailableContext()
    mySysGui!.setContext(CalendarContext)

    rem 'Create the main window
    let MainWindow! = mySysGui!.addWindow(100,100,286,260,TITLE$,$00010013$)

    rem 'Add the calender (grid) to the main window
    let Calendar! = MainWindow!.addGrid(100,3,26,278,221)

    rem 'Set the attributes of the grid
    Calendar!.setGridEditable(1)
    blueColor! = mySysGui!.makeColor(mySysGui!.BLUE)
    Calendar!.setColumnHeaderForeColor(blueColor!)
    Calendar!.setNumRows(6)
    Calendar!.setRowHeight(20)
    Calendar!.setNumColumns(7)
    Calendar!.setMaxColumns(255)
    Calendar!.setHasColumnHeader(mySysGui!.TRUE)
    Calendar!.setVerticalLinesVisible(mySysGui!.TRUE)
    Calendar!.setHorizontalLinesVisible(mySysGui!.TRUE)
    Calendar!.setClientEdge(mySysGui!.TRUE)
    Calendar!.setSelectionMode(Calendar!.GRID_SELECT_CELL)

    rem 'Set the attributes for the grid's columns
    FOR COL = 0 TO 6
        Calendar!.setColumnWidth(COL, 39)
        Calendar!.setColumnAlignment(Col,Calendar!.GRID_ALIGN_RIGHT)
        Calendar!.setColumnForeColor(COL, blueColor!)
    NEXT COL

    rem 'Set the attributes for the grid's column headers
    myVector! = mySysGui!.makeVector()
    myVector!.addItem("S")
    myVector!.addItem("M")
    myVector!.addItem("T")
    myVector!.addItem("W")
    myVector!.addItem("T")
    myVector!.addItem("F")
    myVector!.addItem("S")
    Calendar!.setColumnHeaderText(myVector!)
    Calendar!.setColumnHeaderForeColor(blueColor!)

    rem 'Set the attributes for the current date (static text control)
    let CurrDate! = MainWindow!.addStaticText(101,45,3,90,20,"")
    CurrDate!.setClientEdge(mySysGui!.TRUE)
    CurrDate!.setForeColor(blueColor!)
return