BBjStandardGrid::setRowHeaderCellImage

Description

In BBj 5.0 and higher, this method sets the image displayed in a BBjStandardGrid row header cell.

Syntax

Return Value Method

void

setRowHeaderCellImage(int row, BBjImage image!)

Parameters

Variable Description

row

Specifies the row of cell for which image is set.

image!

Specifies the BBjImage to display in the cell.

Return Value

None.

Remarks

None.

Example

rem ' BBjStandardGrid::setRowHeaderCellImage
title$ = "BBjStandardGrid::setRowHeaderCellImage"
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
window! = sysgui!.addWindow(50,50,600,500,title$,$00090083$)
window!.setCallback(window!.ON_CLOSE,"eoj")
window!.setCallback(window!.ON_RESIZE,"resize")
imageManager! = sysgui!.getImageManager()
image$ = "com/basis/bbj/images/demoicons.gif"
image! = imageManager!.loadImageFromServerJar(image$)
imagelist = 1000
width = 16
sysgui!.addImageList(imagelist,width,image!)
rows = 9, cols = 9
grid! = window!.addGrid(101,102,103,25,25,550,450,$91ce$,rows,cols)
grid!.setLineColor(BBjColor.LIGHT_GRAY)
grid!.setColumnHeaderHeight(40)
grid!.setRowHeight(40)
grid!.setRowHeaderWidth(100)
grid!.setFitToGrid(1)
grid!.setSnapToRowHeight(0)
for i = 0 to cols-1
  index = mod(i,4)
  image! = imageManager!.loadImageFromImageList(imagelist,index)
  grid!.setColumnHeaderCellText(i,str(i))
  grid!.setRowHeaderCellText(i,str(i))
  grid!.setRowHeaderCellImage(i,image!)
  grid!.setColumnHeaderCellImage(i,image!)
next i
process_events
eoj:
  release
resize:
  event! = sysgui!.getLastEvent()
  grid!.setSize(event!.getWidth()-50,event!.getHeight()-50)
return

See Also

BBjAPI

BBjSysGui

BBjControl

BBjWindow

See the BBj Object Diagram for an illustration of the relationship between BBj Objects.