BBjTabCtrl::setSelectedIndex

rem ' BBjTabCtrl::setSelectedIndex
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
window! = sysgui!.addWindow(50,50,400,425,"setSelectedIndex",$00090003$)
window!.setCallback(window!.ON_CLOSE,"eoj")
status! = window!.addStatusBar(99)
tabctrl! = window!.addTabCtrl(101,25,25,350,250)
tabctrl!.setName("BBjTabCtrl")
tabctrl!.setCallback(TabCtrl!.ON_TAB_SELECT,"event")
tabctrl!.setCallback(TabCtrl!.ON_TAB_DESELECT,"event")
tabctrl!.setCallback(tabctrl!.ON_GAINED_FOCUS,"focus")
tabctrl!.setCallback(tabctrl!.ON_LOST_FOCUS,"focus")
context = sysgui!.getContext()
tabs = 10
for i = 0 to tabs-1
  child! = window!.addChildWindow(200+I,75,75,100,100,"",$$,context+i+1,$$)
  text$ = "Child " + str(I)
  text! = child!.addStaticText(300+i,25,25,100,50,text$)
  tab$ = "Tab " + str(i)
  tabctrl!.addTab(tab$,child!)
next i
fireEvents! = window!.addCheckBox(102,25,300,350,25,"fireEvents",$0004$)
button! = window!.addButton(1,25,350,350,25,"Random setSelectedIndex")
button!.setName("BBjButton")
button!.setCallback(button!.ON_BUTTON_PUSH,"setSelectedIndex")
button!.setCallback(button!.ON_GAINED_FOCUS,"focus")
button!.setCallback(button!.ON_LOST_FOCUS,"focus")
tabctrl!.setSelectedIndex(2)
tabctrl!.focus()
process_events
eoj:
  release
event:
  event! = sysgui!.getLastEvent()
  event$ = event!.getEventName()+" "+str(event!.getIndex())
  print event$
  status!.setText(event$)
  System.out.println(event$)
return
setSelectedIndex:
  index = rnd(tabs)
  tabctrl!.setSelectedIndex(index,fireEvents!.isSelected(),err=*next); return
  tabctrl!.setSelectedIndex(index)
return
focus:
  event! = sysgui!.getLastEvent()
  print event!.getEventName()," ",event!.getControl().getName()
return