rem ' BBjBuiManager::setTitle
declare BBjSysGui sysgui!
declare BBjBuiManager bui!
declare BBjBusyIndicator busy!
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
bui! = bbjapi().getBuiManager()
url$ = "(Not BUI)"
url$ = bui!.getUrl(err=*next)
appName$ = " (Not BUI)"
appName$ = bui!.getApplicationName(err=*next)
title$ = "BBjBuiManager: " + appName$
touch = 0
touch = bui!.isTouchSupported(err=*next)
if touch then title$ = title$ + " (Touch)" else title$ = title$ + " (Not Touch)"
title$ = title$ + ": " + info(3,2)
window! = sysgui!.addWindow(25,25,450,525,title$,$00090003$)
window!.setCallback(window!.ON_CLOSE,"eoj")
window!.addStaticText(90,25,25,400,25,"URL: "+url$,$$)
window!.addStaticText(91,5,75,40,25,"Title:",$8000$)
title$ = window!.getTitle()
title$ = bui!.getTitle(err=*next)
title! = window!.addEditBox(92,50,70,275,25,title$,$$)
setTitle! = window!.addButton(93,340,70,75,25,"Set",$$)
setTitle!.setCallback(setTitle!.ON_BUTTON_PUSH,"setTitle")
window!.addGroupBox(100,25,125,400,125,"End Actions")
endApp! = window!.addRadioButton(101,30,150,75,25,"App",$0020$)
endUrl! = window!.addRadioButton(102,105,150,75,25,"URL",$0020$)
endMsg! = window!.addRadioButton(103,180,150,75,25,"Msg",$0020$)
endNone! = window!.addRadioButton(104,255,150,75,25,"None",$0020$)
endDefault! = window!.addRadioButton(105,330,150,75,25,"Default",$0020$)
endGroup! = window!.addRadioGroup()
endGroup!.add(endApp!)
endGroup!.add(endUrl!)
endGroup!.add(endMsg!)
endGroup!.add(endNone!)
endGroup!.add(endDefault!)
window!.addStaticText(106,30,200,60,25,"Value:",$8000$)
endValue! = window!.addEditBox(107,100,200,225,25,$$)
setEndAction! = window!.addButton(108,340,200,75,25,"Set",$$)
setEndAction!.setCallback(setEndAction!.ON_BUTTON_PUSH,"setEndAction")
window!.addGroupBox(200,25,275,400,125,"Err Actions")
errApp! = window!.addRadioButton(201,30,300,75,25,"App",$0020$)
errUrl! = window!.addRadioButton(202,105,300,75,25,"URL",$0020$)
errMsg! = window!.addRadioButton(203,180,300,75,25,"Msg",$0020$)
errNone! = window!.addRadioButton(204,255,300,75,25,"None",$0020$)
errDefault! = window!.addRadioButton(205,330,300,75,25,"Default",$0020$)
errGroup! = window!.addRadioGroup()
errGroup!.add(errApp!)
errGroup!.add(errUrl!)
errGroup!.add(errMsg!)
errGroup!.add(errNone!)
errGroup!.add(errDefault!)
window!.addStaticText(206,30,350,60,25,"Value:",$8000$)
errValue! = window!.addEditBox(207,100,350,225,25,$$)
setErrAction! = window!.addButton(208,340,350,75,25,"Set",$$)
setErrAction!.setCallback(setEndAction!.ON_BUTTON_PUSH,"setErrAction")
title$ = "Show Confirm Close Dialog"
confirm = 0
confirm = bui!.getShowConfirmCloseDialog(err=*next)
flags$ = iff(confirm,$0004$,$0000$)
setShowConfirmDialog! = window!.addCheckBox(209,25,425,300,25,title$,flags$)
setShowConfirmDialog!.setCallback(setShowConfirmDialog!.ON_CHECK_ON,"showConfirmDialogOn")
setShowConfirmDialog!.setCallback(setShowConfirmDialog!.ON_CHECK_OFF,"showConfirmDialogOff")
showBusy! = window!.addButton(1,25,475,100,25,"Busy",$$)
showBusy!.setCallback(showBusy!.ON_BUTTON_PUSH,"showBusy")
busyMessage! = window!.addEditBox(300,150,475,200,25,"Working...",$$)
gosub fetch
process_events
eoj:
release
fetch:
endAction! = bui!.getEndAction(err=*return)
switch endAction!.getActionType()
case endAction!.ACTION_APP
endApp!.setSelected(1)
endValue!.setText(endAction!.getAppName())
break
case endAction!.ACTION_URL
endUrl!.setSelected(1)
endValue!.setText(endAction!.getUrl())
break
case endAction!.ACTION_MSG
endMsg!.setSelected(1)
endValue!.setText(endAction!.getMessage())
break
case endAction!.ACTION_NONE
endNone!.setSelected(1)
endValue!.setText("")
break
case endAction!.ACTION_DEFAULT
endDefault!.setSelected(1)
endValue!.setText("")
break
swend
errAction! = bui!.getErrAction(err=*return)
switch errAction!.getActionType()
case errAction!.ACTION_APP
errApp!.setSelected(1)
errValue!.setText(errAction!.getAppName())
break
case errAction!.ACTION_URL
errUrl!.setSelected(1)
errValue!.setText(errAction!.getUrl())
break
case errAction!.ACTION_MSG
errMsg!.setSelected(1)
errValue!.setText(errAction!.getMessage())
break
case errAction!.ACTION_NONE
errNone!.setSelected(1)
errValue!.setText("")
break
case errAction!.ACTION_DEFAULT
errDefault!.setSelected(1)
errValue!.setText("")
break
swend
return
setEndAction:
if endApp!.isSelected() then action! = bui!.appAction(endValue!.getText())
if endUrl!.isSelected() then action! = bui!.urlAction(endValue!.getText())
if endMsg!.isSelected() then action! = bui!.msgAction(endValue!.getText())
if endNone!.isSelected() then action! = bui!.noneAction()
if endDefault!.isSelected() then action! = bui!.defaultAction()
bui!.setEndAction(action!,err=*return)
return
setErrAction:
if errApp!.isSelected() then action! = bui!.appAction(errValue!.getText())
if errUrl!.isSelected() then action! = bui!.urlAction(errValue!.getText())
if errMsg!.isSelected() then action! = bui!.msgAction(errValue!.getText())
if errNone!.isSelected() then action! = bui!.noneAction()
if errDefault!.isSelected() then action! = bui!.defaultAction()
bui!.setErrAction(action!,err=*return)
return
showConfirmDialogOn:
bui!.setShowConfirmCloseDialog(1,err=*next)
return
showConfirmDialogOff:
bui!.setShowConfirmCloseDialog(0,err=*next)
return
setTitle:
bui!.setTitle(title!.getText(),err=*return)
return
showBusy:
busy! = bui!.getBusyIndicator(err=*return)
busy!.setText(busyMessage!.getText())
busy!.setVisible(1)
wait 3
busy!.setVisible(0)
return
|
