GSelectionDialog::setMultipleSelection

Description

In BBj 11.0 and higher, this method sets whether more than one document can be selected at a time in the dialog.

Syntax

Return Value	Method
void	setMultipleSelection(boolean selection)

Parameters

Variable	Description
selection	Specify true (1) to allow selection of more than one document in the dialog. Otherwise specify false (0).

Return Values

None.

Remarks

When multiple item selection is allowed, a mouse left click with no keyboard modifier selects the clicked item and deselects any previously clicked items.

Mouse left click with CMD key pressed (macOS) or CTRL key pressed (Windows) selects the clicked item without deselecting previously clicked items.

Mouse left click with SHIFT key pressed selects the entire range between the previously clicked item through the current clicked item.

Example

rem Use statements
use ::gapps.bbj::GDocFolderSelectionDialog
use ::gapps.bbj::GDocSaveDialog
use ::gapps.bbj::GDocOpenDialog
use ::gapps.bbj::GDoc

rem Run a demo  

rem mode$="folder"
rem mode$="save"

rem Create a folder selection dialog
declare GDocFolderSelectionDialog folderSelectionDialog!
folderSelectionDialog! = new GDocFolderSelectionDialog()
rc = folderSelectionDialog!.doModal()

if (rc = GDocFolderSelectionDialog.getSELECTED())
  documentFolder$ = folderSelectionDialog!.getDocumentFolder()
  x=MsgBox(documentFolder$,0,"Selected folder")
endif

rem Create a save dialog
declare GDocSaveDialog saveDialog!
saveDialog! = new GDocSaveDialog()
saveDialog!.setDefaultType(GDoc.getSPREADSHEET_TYPE())
rc = saveDialog!.doModal()

if (rc = GDocSaveDialog.getSELECTED())
  title$ = saveDialog!.getDocumentTitle()
  type$ = saveDialog!.getDocumentType()
  folder$ = saveDialog!.getDocumentFolder()
  x=MsgBox(folder$ +"/" + title$,0,"Selected document")
endif

rem Create a open dialog
declare GDocOpenDialog openDialog!
openDialog! = new GDocOpenDialog()
openDialog!.setTitle("Google Documents")
openDialog!.setMultipleSelection(1)

rc = openDialog!.doModal()

if (rc = GDocOpenDialog.getSELECTED())
  declare BBjVector selectedDocs!    

  selectedDocs! = openDialog!.getSelectedDocs()
  numSelectedDocs = selectedDocs!.size()

  if (numSelectedDocs > 0)
      for i = 0 to numSelectedDocs-1
          declare GDoc selectedDoc!
          selectedDoc! = cast(GDoc,selectedDocs!.getItem(i))
          selectedDoc!.openInBrowser()
      next i
  endif
endif

release