BBjAPI::getMDI

Description

In BBj 3.0 and higher this method returns a BBjMDI object that represents a SYSGUI window.

Syntax

Return Value

Method

BBjMDI

getMDI()

Parameters

None.

Return Value

Returns a BBjMDI object.

Remarks

None.

Example

REM open the sysGui
sysgui = unt
open(sysgui)"X0"

REM retrieve the MDIProxy

mdi! = BBjAPI().getMDI()

REM create an MDI Window

REM window! = mdi!.makeMDIWindow(50, 50, 800, 600, "MDI Window")
mdi!.createMDIWindow(50, 50, 800, 600, "MDI Window")

REM add menu items to the MDI Window

menuBar! = mdi!.addMenuBar()
AMenu!=menuBar!.addMenu(20,"Sample menu")
MenuItem201! = AMenu!.addMenuItem(201, "Set BBj Command line params")
MenuItem202! = AMenu!.addMenuItem(202, "Set Program Command line params")
MenuItem203! = AMenu!.addMenuItem(203, "Run Program")
MenuItem204! = AMenu!.addMenuItem(204, "add toolbars")
MenuItem205! = AMenu!.addMenuItem(205, "Enable MDI WindowsMenu")

REM set callbacks

MenuItem201!.setCallback(menuBar!.ON_MENU_ITEM_SELECT, "selected_201")
MenuItem202!.setCallback(menuBar!.ON_MENU_ITEM_SELECT, "selected_202")
MenuItem203!.setCallback(menuBar!.ON_MENU_ITEM_SELECT, "selected_203")
MenuItem204!.setCallback(menuBar!.ON_MENU_ITEM_SELECT, "selected_204")
MenuItem205!.setCallback(menuBar!.ON_MENU_ITEM_SELECT, "selected_205")

CALLBACK(ON_CLOSE,APP_CLOSE,mdi!.MDI_CONTEXT)

REM Process Events

PROCESS_EVENTS

REM Callback routine called when the user closes the application window

APP_CLOSE:
mdi!.closeAll(5)
RETURN

selected_201:
print (0,ERR=doReturn) 'GETS'("","commandLineParams: ", cmdLineParams$)
read cmdLineParams$

return

selected_202:
print (0,ERR=doReturn) 'GETS'("","ProgramParams: ", programParams$)
read programParams$
return


selected_203:
filename$ = fileopen("choose file","/","","")
if filename$ <> "::CANCEL::"
    command$ = "bbj " + cmdLineParams$ + " " + filename$ + " - " + programParams$ + " &"
    print "scalling: " , command$
    x = scall(command$)
endif
return


selected_204:

tb1! = mdi!.addToolButton(101,0,0,20,20,"1",$4000$)
tb2! = mdi!.addToolButton(102,0,0,20,20,"2",$4000$)
tb3! = mdi!.addToolButton(103,0,0,20,20,"3",$4000$)

tb1!.setCallback(tb1!.ON_TOOL_BUTTON_PUSH,"tb1")
tb2!.setCallback(tb1!.ON_TOOL_BUTTON_PUSH,"tb2")
tb3!.setCallback(tb1!.ON_TOOL_BUTTON_PUSH,"tb3")

menuItem204!.setEnabled( 0 )
return

TB1:
print "1"
RETURN

TB2:
print "2"
RETURN

TB3:
print "3"
RETURN


selected_205:
mdi!.enableMDIWindowMenu()
menuItem205!.setEnabled( 0 )
RETURN

doReturn:
return

See Also

BBjAPI

Object Variables

See the BBj Object Diagram for an illustration of the relationship between BBj Objects.