BBjWindow::addListButton

Description

Creates a list button control in the BBjWindow.

Syntax

Return Value

Method

BBjListButton

addListButton(int ID, number x, number y, number w, number h, string initialContents)

BBjListButton

addListButton(int ID, number x, number y, number w, number h, string initialContents, string flags)

BBjListButton

addListButton(int ID, string initialContents)

BBjListButton

addListButton(int ID, string initialContents, string flags)

BBjListButton

addListButton(string initialContents)

BBjListButton

addListButton(string initialContents, string flags)

Parameters

Variable

Description

ID

Control ID number. It must be an integer between 1 and 32767 and be unique within a given top-level window.

x

Horizontal position of the upper-left corner of the control in current units.

y

Vertical position of the upper-left corner of the control in current units.

width

Width of the control in current units.

height

Height of the control in current units.

initialContents

Line feed separated strings containing the initial contents of the list.

flags

Control flags, as follows:

Flag Description
$0001$ Sets the control to be initially disabled.
$0010$ Sets the control to be initially invisible.
$0020$ Designates the control to be part of a keyboard navigation group.
$0800$ Draws a recessed client edge around the control.
$1000$ Draws a raised edge around the control.
$2000$ Left justifies list items (BBj 17.0 and higher).
$4000$ Centers list items (BBj 17.0 and higher).
$8000$ Right justifies list items (BBj 17.0 and higher).

Return Value

Returns the created BBjListButton object.

Remarks

The list of choices available may be modified only under program control. The values in the list may be accessed using a zero-based list index integer. Unlike the list edit control, it does not allow a value to be entered manually. As the user types, the first matching selection in the list is placed in the edit area. Various keys may be used to navigate in the list including the Home (first selection), End (last selection), Page Up and Page Down, and the arrow keys.

If the ID parameter is not specified, a control ID is assigned dynamically using getAvailableControlID().

If the x, y, width, and height parameters are not specified, they're all initialized to 0. This is typically for use with DWC windows that dynamically arrange their contents (window creation flag $00100000$).

Example

rem 'Add a list button control to a window

rem 'Obtain the instance of the BBjAPI object
let myAPI!=BBjAPI()

rem 'Open the SysGui device
SYSGUI=UNT
OPEN (SYSGUI) "X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui!=myAPI!.getSysGui()

rem 'Set addWindow param values
X=10
Y=10
WIDTH=200
HEIGHT=200
TITLE$="BBj Window"

rem 'Set the current context
mySysGui!.setContext(0)

rem 'Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

rem 'Add a list button control to the window
myListButton! = myWindow!.addListButton(101,50,100,90,60,"",$0000$)

rem 'Add items into the list button
FOR I=1 TO 4
    ITEM$="ITEM " + STR(I)
    myListButton!.addItem(ITEM$)
NEXT I

rem 'Register the CALLBACK routines
CALLBACK(ON_LIST_SELECT,LIST_ITEM_SELECTED,mySysGui!.getContext(),myListButton!.getID())
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

rem 'Process Events
process_events

rem 'Callback routine called when the user selects an item in the list button
LIST_ITEM_SELECTED:
    rem 'Display a message with the select list button item
    MESSAGE$="The item selected is: " + STR(myListButton!.getItemAt(myListButton!.getSelectedIndex()))
    let X=MSGBOX(MESSAGE$)
return

rem 'Callback routine called when the user closes the application window
APP_CLOSE:
release

See Also

BBjAPI

BBjSysGui

BBjControl

'LISTBUTTON' Mnemonic

See the BBj Object Diagram for an illustration of the relationship between BBj Objects.