BBjWindow::addHorizontalScrollBar

Description

Creates a horizontal scroll bar control in the BBjWindow.

Syntax

Return Value	Method
BBjScrollBar	addHorizontalScrollBar(int ID, int x,int y, int width, int height)
BBjScrollBar	addHorizontalScrollBar(int ID, int x,int y, int width, int height, string flags)

Parameters

Variable	Description
ID	Control ID number. It must be an integer between 1 and 32767 and be unique within a given top-level window.
x	Horizontal position of the upper-left corner of the control in current units.
y	Vertical position of the upper-left corner of the control in current units.
width	Width of the control in current units.
height	Height of the control in current units.
flags	Control flags, as follows:
	Flag $0001$ $0010$ $0800$ $1000$	Description Sets the control to be initially disabled. Sets the control to be initially invisible. Draws a recessed client edge around the control. Draws a raised edge around the control.

Return Value

Returns the created horizontal BBjScrollBar object.

Remarks

A BBjScrollBar should not be confused with scroll bars that can be created with optional flags on windows, child windows, or edit-type controls.

Example

REM Add a horizontal scrollbar control to a window

REM Obtain the instance of the BBjAPI object
LET myAPI!=BBjAPI()

REM Open the SysGui device
SYSGUI=UNT
OPEN (SYSGUI) "X0"

REM Obtain the instance of the BBjSysGui object
LET mySysGui!=myAPI!.getSysGui()

REM Set addWindow param values
X=10
Y=10
WIDTH=200
HEIGHT=200
TITLE$="BBj Window"

REM Set the current context
mySysGui!.setContext(0)

REM Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

REM Add a horizontal scrollbar on the window
myHScrollBar! = myWindow!.addHorizontalScrollBar(101,0,180,200,20,$0000$)

REM Register the CALLBACK routines
CALLBACK(ON_CONTROL_SCROLL,SCROLLBAR_SCROLLED,mySysGui!.getContext(),myHScrollBar!.getID())
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

REM Process Events
PROCESS_EVENTS

REM Callback routine called when the scrollbar is used to scroll
SCROLLBAR_SCROLLED:
REM Display a message that the scrollbar has been used to scroll
MESSAGE$="The scrollbar has been used to scroll"
LET X=MSGBOX(MESSAGE$)
RETURN

REM Callback routine called when the user closes the application window
APP_CLOSE:
RELEASE
RETURN