BBjWindow::addButton

Description

Creates a button in the BBjWindow.

Syntax

Return Value

Method

BBjButton

addButton(int ID, number x, number y, number w, number h, string title)

BBjButton

addButton(int ID, number x, number y, number w, number h, string title, string flags)
BBjButton addButton(int ID, string title)
BBjButton addButton(int ID, string title, string flags)
BBjButton addButton(string title)
BBjButton addButton(string title, string flags)

Parameters

Variable

Description

ID

Control ID number. It must be an integer between 1 and 32767 and be unique within a given top-level window.

x

Horizontal position of the upper-left corner of the control in current units.

y

Vertical position of the upper-left corner of the control in current units.

width

Width of the control in current units.

height

Height of the control in current units.

title

Title of the control. Including the '&' before a character in the title causes it to be an accelerator.

flags

Control flags, as follows:

Flag Description

$0001$ 

 Sets the control to be initially disabled.

$0010$ 

 Sets the control to be initially invisible.

$0020$

 Designates the control to be part of a keyboard navigation group.

$0800$ 

 Draws a recessed client edge around the control.

$1000$ 

 Draws a raised edge around the control.

Return Value

Returns the created BBjButton object.

Remarks

If the ID parameter is not specified, a control ID is assigned dynamically using getAvailableControlID().

If the x, y, width, and height parameters are not specified, they are all initialized to 0. This is typically for use with DWC windows that dynamically arrange their contents (window creation flag $00100000$).

Example

rem ' BBjButton

sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
window! = sysgui!.addWindow(25,25,200,275,"BBjButton",$00090003$)
window!.setCallback(window!.ON_CLOSE,"eoj")
default! = window!.addButton(1,25,25,150,25,"OK",$$)
default!.setToolTipText("BBjButton (Default)")
default!.setCallback(default!.ON_BUTTON_PUSH,"event")
cancel! = window!.addButton(2,25,75,150,25,"Cancel",$$)
cancel!.setToolTipText("BBjButton (Cancel)")
cancel!.setCallback(cancel!.ON_BUTTON_PUSH,"event")
ImageManager! = sysgui!.getImageManager()
openImage! = ImageManager!.loadImageFromServerJar("com/basis/bbj/images/open.gif")
text! = window!.addButton(101,25,125,150,25,"Open",$$)
text!.setToolTipText("BBjButton (Text)")
text!.setCallback(text!.ON_BUTTON_PUSH,"event")
image! = window!.addButton(102,25,175,150,25,"",$$)
image!.setImage(openImage!)
image!.setImageSize(openImage!.getWidth(),openImage!.getHeight())
image!.setToolTipText("BBjButton (Image)")
image!.setCallback(image!.ON_BUTTON_PUSH,"event")
both! = window!.addButton(103,25,225,150,25,"Open",$$)
both!.setImage(openImage!)
both!.setToolTipText("BBjButton (Text+Image)")
both!.setCallback(both!.ON_BUTTON_PUSH,"event")
process_events

eoj:
release

event:
    event! = sysgui!.getLastEvent()
    button! = event!.getButton()
    i = msgbox(button!.getText()+" "+str(button!.getID()),0,event!.getEventName())
return

See Also

BBjAPI

BBjSysGui

BBjControl

BBjWindow

BUTTON Mnemonic - Create a Push Button Control

See the BBj Object Diagram for an illustration of the relationship between BBj Objects.