BBjMenu::addMenuItem

Description

Adds a menu item to the BBjMenu.

Syntax

Return Value	Method
BBjMenuItem	addMenuItem(int ID, string title)
BBjMenuItem	addMenuItem(int ID, string title, int action)
BBjMenuItem	addMenuItem(int ID, string title, boolean checkable, boolean checked)
BBjMenuItem	addMenuItem(int ID, string title, boolean checkable, boolean checked, int action)

Parameters

Variable	Description
ID	Specifies the ID of the menu item to be added.
title	Specifies the title of the menu item.
action	Specifies one of the following special menu actions: 32027 CUT 32028 COPY 32029 PASTE
checkable	A boolean that specifies whether the menu item is checkable.
checked	A boolean value that specifies whether the menu item is checked if it is checkable.

Return Value

Returns the created BBjMenuItem object.

Remarks

None.

Example

REM Add a menu item to a menu

REM Obtain the instance of the BBjAPI object
LET myAPI!=BBjAPI()

REM Open the SysGui device
SYSGUI=UNT
OPEN (SYSGUI) "X0"

REM Obtain the instance of the BBjSysGui object
LET mySysGui!=myAPI!.getSysGui()

REM Set addWindow param values
X=10
Y=10
WIDTH=200
HEIGHT=200
TITLE$="BBj Window"

REM Set the current context
mySysGui!.setContext(0)
REM Create a window with a title in the current context
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

REM Create some edit boxes for doing cut/copy/paste
oneEditBox! = myWindow!.addEditBox(101,10,10,180,30,"first text control")
twoEditBox! = myWindow!.addEditBox(102,10,50,180,30,"second text control")

REM Create the menu bar
myMenuBar!=myWindow!.addMenuBar()

REM Add a menu to the menu bar
myMenu!=myMenuBar!.addMenu(-100,"&Menu")

REM Add menu items to the menu
myMenu!.addMenuItem(-101,"Menu Item 1")
myMenu!.addMenuItem(-102,"Menu Item 2")
myMenu!.addMenuItem(-103,"Cu&t",mySysGui!.CUT)
myMenu!.addMenuItem(-104,"&Copy",mySysGui!.COPY)
myMenu!.addMenuItem(-105,"&Paste",mySysGui!.PASTE)

REM Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

REM Process Events
PROCESS_EVENTS

REM Callback routine called when the user closes the application window
APP_CLOSE:
RELEASE
RETURN