BBjListButton::insertItems

Description

Inserts items into the list of the BBjListButton control.

Syntax

Return Value	Method
void	insertItems(int `index`, BBjVector itemVector!)
void	insertItems(int `index`, string items$)

Parameters

Variable	Description
index	Specifies the 0-based index at which the item will be inserted.
itemVector!	The vector of items to be added to the list.
items$	The linefeed-delimited list of items to be added to the list.

Return Value

None.

Remarks

Each item with an index greater than or equal to the specified index, plus the number of items in the vector or the linefeed-delimited list, is shifted upward to have an index equal to one plus the number of items in the vector or the linefeed-delimited list than the value it had previously.

Example 1

rem 'Insert items in a vector into a list button control

rem 'Obtain the instance of the BBjAPI object
let myAPI! = BBjAPI()

rem 'Open the SysGui device
SYSGUI = UNT
OPEN (SYSGUI) "X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui! = myAPI!.getSysGui()

rem 'Set addWindow param values
X = 10
Y = 10
WIDTH = 200
HEIGHT = 200
TITLE$="BBj Window"

rem 'Set the current context
mySysGui!.setContext(0)

rem 'Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

rem 'Add a list button control to the window
myListButton! = myWindow!.addListButton(101,50,100,90,60,"",$0000$)

rem 'Make a vector that will contain list items
myVector! = mySysGui!.makeVector()

rem 'Insert items into the vector
FOR I = 1 TO 4
    ITEM$="ITEM " + STR(I)
    myVector!.addItem(ITEM$)
NEXT I

rem 'Insert items in the vector into the list button control
myListButton!.insertItems(0,myVector!)

rem 'Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

rem 'Process Events
process_events

rem 'Callback routine called when the user closes the application window
APP_CLOSE:
release

Example 2

rem 'Insert items in a string into a list button control

rem 'Obtain the instance of the BBjAPI object
let myAPI! = BBjAPI()

rem 'Open the SysGui device
SYSGUI = UNT
OPEN (SYSGUI) "X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui! = myAPI!.getSysGui()

rem 'Set addWindow param values
X = 10
Y = 10
WIDTH = 200
HEIGHT = 200
TITLE$="BBj Window"

rem 'Set the current context
mySysGui!.setContext(0)

rem 'Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

rem 'Add a list button control to the window
myListButton! = myWindow!.addListButton(101,50,100,90,60,"",$0000$)

rem 'Make a string that will contain list items
ITEMS$ = ""

rem 'Insert items into the vector
FOR I = 1 TO 4
    ITEM$="ITEM " + STR(I)
    ITEMS$ = ITEMS$+ITEM$+$0A$
NEXT I

rem 'Insert items in the string into the list button control
myListButton!.insertItems(0,ITEMS$)

rem 'Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

rem 'Process Events
process_events

rem 'Callback routine called when the user closes the application window
APP_CLOSE:
release