BBjPopupMenu::removeMenuItemAt

Description

In BBj 3.0 and higher, this method removes a menu item from a BBjPopupMenu.

Syntax

Return Value	Method
void	removeMenuItemAt(int `index`)

Parameters

Variable	Description
index	Specifies the 0-based index of the menu item to be removed.

Return Value

None.

Remarks

Each menu item in the menu with an index greater than the removed menu item's index is shifted downward to have an index one smaller than the value it had previously.

Example

rem 'Remove a menu item from a popup menu

rem 'Obtain the instance of the BBjAPI object
let myAPI! = BBjAPI()

rem 'Open the SysGui device
SYSGUI = UNT
OPEN (SYSGUI)"X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui! = myAPI!.getSysGui()

rem 'Set addWindow param values
X = 100
Y = 100
WIDTH = 200
HEIGHT = 100
TITLE$="BBj Window"

rem 'Set the current context
mySysGui!.setContext(0)

rem 'Create a window with a title in the current context
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

rem 'Create a button
myButton! = myWindow!.addButton(1,55,35,90,30,"OK")

rem 'Add a popup menu to the button
myPopupMenu! = myButton!.addPopupMenu()

rem 'Add menu items, including a separator, to the popup menu
myItem1! = myPopupMenu!.addMenuItem(-201,"Item 1")
myItem2! = myPopupMenu!.addMenuItem(-202,"Item 2")
myPopupMenu!.addSeparator()
myItem3! = myPopupMenu!.addMenuItem(-203,"Item 3",1,0)
myItem4! = myPopupMenu!.addMenuItem(-204,"Item 4",1,1)

rem 'Remove the menu item from index = 1
myPopupMenu!.removeMenuItemAt(1)

rem 'Register the CALLBACK routines
CALLBACK(ON_BUTTON_PUSH,OK,mySysGui!.getContext(),myButton!.getID())
CALLBACK(ON_POPUP_ITEM_SELECT,Item1,myPopupMenu!.getID(),myItem1!.getID())
CALLBACK(ON_POPUP_ITEM_SELECT,Item2,myPopupMenu!.getID(),myItem2!.getID())
CALLBACK(ON_POPUP_ITEM_SELECT,Item3,myPopupMenu!.getID(),myItem3!.getID())
CALLBACK(ON_POPUP_ITEM_SELECT,Item4,myPopupMenu!.getID(),myItem4!.getID())
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

rem 'Process Events
process_events

rem 'Callback routine invoked when the user clicks the button
OK:
    i = msgbox("OK Button was selected")
return

rem 'Callback routine invoked when the popup menu is being opened
ShowPopup:
    print "Popup Menu was opened"
return

rem 'Callback routine invoked when the popup menu is being closed
HidePopup:
    print "Popup Menu was closed"
return

rem 'Callback routine invoked when the user selects the first item
Item1:
    i = msgbox("Item 1 was selected")
return

rem 'Callback routine invoked when the user selects the second item
Item2:
    i = msgbox("Item 2 was selected")
return

rem 'Callback routine invoked when the user selects the third item
Item3:
    if myItem3!.isSelected() then state$="ON" else state$="OFF"
    i = msgbox("Item 3 was selected and is now checked "+state$)
return

rem 'Callback routine invoked when the user selects the fourth item
Item4:
    if myItem4!.isSelected() then state$="ON" else state$="OFF"
    i = msgbox("Item 4 was selected and is now checked "+state$)
return

rem 'Callback routine called when the user closes the application window
APP_CLOSE:
release