BBjPopupMenu::getClassList

Description

In BBj 23.00 and higher, this method returns a BBjVector containing all CSS class names currently defined on this BBjPopupMenu.

Syntax

Return Value	Method
BBjVector	getClassList()

Parameters

None.

Return Value

Returns a BBjVector containing all CSS class names currently defined on this BBjPopupMenu.

Remarks

For more details, see CSS API.

Example

rem ' BBjPopupMenu::getClassList

sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()

title$ = "BBjPopupMenu::getClassList"
window! = sysgui!.addWindow(25,25,350,350,title$,$00090083$)
window!.setCallback(window!.ON_CLOSE,"eoj")

text$ = "BBjControl with right-click BBjPopupMenu."
text! = window!.addStaticText(100,25,25,300,25,text$)

popup! = text!.addPopupMenu()
item! = popup!.addMenuItem(-1,"Popup Menu Item")

window!.addStaticText(101,25,75,50,25,"Class:",$8000$)
class! = window!.addEditBox(102,100,75,225,25,"xyzzy",$$)

addClass! = window!.addButton(103,100,125,225,25,"addClass")
addClass!.setCallback(addClass!.ON_BUTTON_PUSH,"addClass")

removeClass! = window!.addButton(104,100,175,225,25,"removeClass")
removeClass!.setCallback(removeClass!.ON_BUTTON_PUSH,"removeClass")

toggleClass! = window!.addButton(2,100,225,225,25,"toggleClass")
toggleClass!.setCallback(toggleClass!.ON_BUTTON_PUSH,"toggleClass")

getClassList! = window!.addButton(1,100,275,225,25,"getClassList")
getClassList!.setCallback(getClassList!.ON_BUTTON_PUSH,"getClassList")

process_events

eoj:
  release

addClass:
  popup!.addClass(class!.getText(),err=*next); return
  i = msgbox(errmes(-1),0,"addClass")
return

removeClass:
  popup!.removeClass(class!.getText(),err=*next); return
  i = msgbox(errmes(-1),0,"removeClass")
return

toggleClass:
   class$ = class!.getText()
   toggle! = popup!.toggleClass(class$,err=oops)
   classList! = popup!.getClassList()
   title$ = "toggleClass "+class$+" = "+Boolean.toString(toggle!)
   i = msgbox("getClassList = "+str(classList!),0,title$)
return
oops:
  i = msgbox(errmes(-1),0,"toggleClass")
return

getClassList:
   classList! = popup!.getClassList()
   i = msgbox(str(classList!),0,"getClassList()")
return