Interface TextControl::setMaxSuggestions

Description

In BBj 7.0 and higher, this method sets the maximum number of suggestions to be returned by getSuggestions or presented when the user right-clicks on a misspelled word.

Syntax

Return Value	Method
void	setMaxSuggestions(int `count`)

Parameters

Variable	Description
count	The maximum number of suggestions to be returned by getSuggestions() or presented when the user right-clicks on a misspelled word.

Return Value

None.

Remarks

The default number of suggestions is 8.

Example

rem ' setMaxSuggestions

SYSGUI=UNT
OPEN (SYSGUI)"X0"

sysgui! = BBjAPI().getSysGui()
window! = sysgui!.addWindow(200,200,400,400,"Spell-Check setMaxSuggestions",$00010003$)
suggest! = window!.addButton(1,25,10,150,30,"Get Suggestions")
cedit! = window!.addCEdit(102,25,50,350,325,"",$0100$)
cedit!.setLineWrap(1)

Locale$ = stbl("!LOCALE","en_GB")
cedit!.setSpellChecked(1)

gosub InitText

CALLBACK(ON_BUTTON_PUSH,Suggest,suggest!.getContextID(),suggest!.getID())
CALLBACK(ON_CLOSE,APP_CLOSE,sysgui!.getContext())

REM Process Events
PROCESS_EVENTS

APP_CLOSE:
RELEASE

Suggest:
  cedit!.setMaxSuggestions(rnd(3)+1)
  Suggestions=cedit!.getMaxSuggestions()
  words!=cedit!.getMisspelledWords()
  print "There are",words!.size()," misspelled words."
  print "Report the top",Suggestions," suggestions for each misspelled word."
  if words!.size() then
:    for word=0 to words!.size()-1;
:        word$ = words!.get(word);
:        Suggestions! = cedit!.getSuggestions(word$);
:        print "Suggestions for '"+word$+"': ",Suggestions!;
: next word
  print 'lf',
return

InitText:
  Text! = new java.util.HashMap()
  while 1
    dread text$,err=*break
    cedit!.addParagraph(-1,text$)
  wend
return

data "CHAPTER I"
data "Down the Rabbit-Hole"
data "Alice was begining to get very tired of sitting by her sister on the bank, and of having nothing to do: once or twice she had peeped into the book her sister was reading, but it had no pictures or conversations in it, 'and what is the use of a book,' thought Alice 'without pictures or conversation?'"

data "So she was considerring in her own mind (as well as she could, for the hot day made her feel very sleepy and stupid), whether the pleasure of making a daisy-chain would be worth the trouble of getting up and picking the daisies, when suddenly a White Rabbit with pink eyes ran close by her."

data "There was nothing so very remarkable in that; nor did Alice think it so very much out of the way to hear the Rabbit say to itself, 'Oh dear! Oh dear! I shall be late!' (when she thought it over afterwards, it occured to her that she ought to have wondered at this, but at the time it all seemed quite natural); but when the Rabbit actually took a watch out of its waistcoat-pocket, and looked at it, and then hurried on, Alice started to her feet, for it flashed across her mind that she had never before seen a rabbit with either a waistcoat-pocket, or a watch to take out of it, and burning with curiousity, she ran across the field after it, and fortunatly was just in time to see it pop down a large rabbit-hole under the hedge."