BBjGridCellSelectionChangedEvent::getSelectedCells

Description

In BBj 19.20 and higher, this method returns a BBjVector containing the selected cells in a grid. If the grid is in multiple selection mode (BBjGrid::setMultipleSelection) and the Enhanced Selection Model is enabled using BBjGrid::setEnhancedSelectionModelEnabled, then the BBjVector may contain multiple cells.

Syntax

Return Value	Method
BBjVector	getSelectedCells()

Parameters

None.

Return Value

This method returns a BBjVector containing zero or more BBjGridCell indicating the currently selected cells.

Remarks

This method will only work when BBjGrid::setSelectionMode is set to GRID_SELECT_CELL and fires when one or more cells are either selected deselected.

Example

rem ' BBjGridCellSelectionChangedEvent Example

sysgui = unt
open (sysgui)"X0"

declare BBjAPI bbjapi!
declare BBjSysGui sysgui!
declare BBjTopLevelWindow window!
declare BBjStandardGrid grid!

bbjapi! = BBjAPI()
sysgui! = bbjapi!.getSysGui()
window! = sysgui!.addWindow(100,100,400,300,"Test Grid getSelectedCount",$00010003$)
window!.setCallback(bbjapi!.ON_CLOSE,"eoj")

rows=10,cols=10
grid! = window!.addGrid(101,10,10,580,350)

grid!.setEnhancedSelectionModelEnabled(1)

grid!.setDefaultColumnWidth(50)
grid!.setRowHeight(23)
grid!.setMultipleSelection(1)
grid!.setSelectionMode(grid!.GRID_SELECT_CELL)
grid!.setNumRows(rows)
grid!.setNumColumns(cols)
gridvec! = bbjapi!.makeVector()
for row = 0 to rows-1
    for col = 0 to cols-1
        text$=str(row:"00")+","+str(col:"00")
        gridvec!.addItem(text$)
    next col
next row
grid!.setCellText(0,0,gridvec!)

grid!.setCallback(grid!.ON_CELL_SELECTION_CHANGE,"cell_selection_changed")

counter = 0

process_events

eoj:
release

cell_selection_changed:
    ev! = cast(BBjGridCellSelectionChangedEvent,sysgui!.getLastEvent())
    Print "Cell Selection Changed"
    Print "ev!.getColumn()= ",ev!.getColumn()
    Print "ev!.getRow()= ", ev!.getRow()

    Print "ev!.getSelectedCells() = ", ev!.getSelectedCells()
    Print "ev!.getSelectedCellCount() = ", ev!.getSelectedCellCount()
    Print
    counter = counter + 1
    Print counter
    Print
return