BBjGrid::setShouldHighlightSelectedRow

Description

In BBj 6.0 and higher, this method sets whether the grid will highlight the entire row containing the currently selected cell.

Syntax

Return Value	Method
void	setShouldHighlightSelectedRow(int `p_should`)

Parameters

Variable	Description
p_should	Indicates whether the grid should highlight the entire row containing the currently selected cell.

Return Value

None.

Remarks

By default, a grid does not highlight the entire row of the currently selected cell.

Example

rem 'Highlight the Selected Row

rem 'Obtain the instance of the BBjAPI object
let myAPI!=BBjAPI()

rem 'Open the SysGui device
SYSGUI=UNT
OPEN (SYSGUI) "X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui!=myAPI!.getSysGui()

rem 'Set addWindow param values
X=10
Y=10
WIDTH=400
HEIGHT=400
TITLE$="BBj Window"

rem 'Set the current context
mySysGui!.setContext(0)

rem 'Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$,$000002$)

rem 'Add a grid on the window
myGrid! = myWindow!.addGrid(101,50,100,300,300,$8060$,4,2)

rem 'Set the grid properties
myGrid!.setDefaultColumnWidth(130)
myGrid!.setGridEditable(1)

rem 'Add text to the grid cells
FOR ROW = 0 TO 3
    FOR COL = 0 TO 1
        CELLTEXT$="row = " + STR(ROW+1) + ", col = " + STR(COL+1)
        myGrid!.setCellText(ROW,COL,CELLTEXT$)
    NEXT COL
NEXT ROW

rem 'set should highlight selected row
myGrid!.setShouldHighlightSelectedRow(1)

rem 'check should highlight selected row
if (myGrid!.getShouldHighlightSelectedRow()=1) then
    print "ShouldHighlightSelectedRow() is active"
else
    print "ShouldHighlightSelectedRow() is not active"
endif

rem 'Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

rem 'Process Events
process_events

rem 'Callback routine called when the user closes the application window
APP_CLOSE:
release