BBjGrid::setCellVerticalAlignment

rem ' BBjGrid::setCellVerticalAlignment
sysgui! = bbjapi().openSysGui("X0")
title$ = "BBjGrid::setCellVerticalAlignment"
window! = sysgui!.addWindow(25,25,800,600,title$,$00090083$)
window!.setCallback(window!.ON_CLOSE,"eoj")
window!.setCallback(window!.ON_RESIZE,"resize")
styles! = window!.addRadioGroup()
inpute! = window!.addRadioButton(91,25,25,175,25,"GRID_STYLE_INPUTE",$0004$)
inpute!.setCallback(inpute!.ON_CHECK_ON,"grid_style_inpute")
styles!.add(inpute!)
button! = window!.addRadioButton(92,200,25,175,25,"GRID_STYLE_BUTTON_UP",$0000$)
button!.setCallback(button!.ON_CHECK_ON,"grid_style_button_up")
styles!.add(button!)
label! = window!.addRadioButton(93,375,25,175,25,"GRID_STYLE_LABEL",$0000$)
label!.setCallback(label!.ON_CHECK_ON,"grid_style_label")
styles!.add(label!)
text! = window!.addRadioButton(94,550,25,175,25,"GRID_STYLE_TEXT",$0000$)
text!.setCallback(text!.ON_CHECK_ON,"grid_style_text")
styles!.add(text!)
status! = window!.addStatusBar(100)
grid! = window!.addGrid(101,25,75,750,500,$8046$,3,3)
grid!.setEditable(1)
grid!.setLineColor(BBjColor.LIGHT_GRAY)
grid!.setRowHeight(150)
grid!.setDefaultColumnWidth(220)
grid!.setMainGridVerticalAlignment(grid!.GRID_ALIGN_BOTTOM)
grid!.setRowHeaderCellVerticalAlignment(0,grid!.GRID_ALIGN_TOP)
grid!.setRowHeaderCellVerticalAlignment(1,grid!.GRID_ALIGN_CENTER)
grid!.setRowHeaderCellVerticalAlignment(2,grid!.GRID_ALIGN_BOTTOM)
grid!.setColumnHeaderCellAlignment(0,grid!.GRID_ALIGN_LEFT)
grid!.setColumnHeaderCellAlignment(1,grid!.GRID_ALIGN_CENTER)
grid!.setColumnHeaderCellAlignment(2,grid!.GRID_ALIGN_RIGHT)
for col=0 to 2
  grid!.setColumnHeaderCellText(col,str(col))
next col
info$ = ""
info$ = info$ + "LEFT="+str(grid!.GRID_ALIGN_LEFT)
info$ = info$ + " CENTER="+str(grid!.GRID_ALIGN_CENTER)
info$ = info$ + " RIGHT="+str(grid!.GRID_ALIGN_RIGHT)
info$ = info$ + "; TOP="+str(grid!.GRID_ALIGN_TOP)
info$ = info$ + " CENTER="+str(grid!.GRID_ALIGN_CENTER)
info$ = info$ + " BOTTOM="+str(grid!.GRID_ALIGN_BOTTOM)
print info$
status!.setText(info$)
for row=0 to 2
  grid!.setRowHeaderCellText(row,str(row))
  for col=0 to 2
    grid!.setCellText(row,col,str(row)+","+str(col))
    r = 128 + rnd(128), g = 128 + rnd(128), b = 128 + rnd(128)
    grid!.setCellBackColor(row,col,sysgui!.makeColor(r,g,b))
    if row=0 then grid!.setCellVerticalAlignment(row,col,grid!.GRID_ALIGN_TOP)
    if row=1 then grid!.setCellVerticalAlignment(row,col,grid!.GRID_ALIGN_CENTER)
    if row=2 then grid!.setCellVerticalAlignment(row,col,grid!.GRID_ALIGN_BOTTOM)
    if col=0 then grid!.setCellAlignment(row,col,grid!.GRID_ALIGN_LEFT)
    if col=1 then grid!.setCellAlignment(row,col,grid!.GRID_ALIGN_CENTER)
    if col=2 then grid!.setCellAlignment(row,col,grid!.GRID_ALIGN_RIGHT)
    info$ = "row "+str(row)+" col "+str(col)
    info$ = info$ + " getCellAlignment="+str(grid!.getCellAlignment(row,col))
    info$ = info$ + " getCellVerticalAlignment="+str(grid!.getCellVerticalAlignment(row,col))
    print info$
    grid!.setToolTipText(row,col,info$)
  next col
next row
process_events
eoj:
  release
resize:
  event! = sysgui!.getLastEvent()
  grid!.setSize(event!.getWidth()-50,event!.getHeight()-100)
return
grid_style_inpute:
  grid!.setDefaultGridStyle(grid!.GRID_STYLE_INPUTE)
return
grid_style_button_up:
  grid!.setDefaultGridStyle(grid!.GRID_STYLE_BUTTON_UP)
return
grid_style_label:
  grid!.setDefaultGridStyle(grid!.GRID_STYLE_LABEL)
return
grid_style_text:
  grid!.setDefaultGridStyle(grid!.GRID_STYLE_TEXT)
return