BBjWindow::isSimpleWindow

Description

In BBj 22.00 and higher, this method returns a boolean indicating whether this window is implemented on the client in a simplified structure that doesn't support status bars or internal docked child windows.

Syntax

Return Value	Method
boolean	isSimpleWindow()

Parameters

None.

Return Value

Remarks

This option is only meaningful for BBjChildWindows in the DWC client. See BBjWindow::addChildWindow.

Example

rem ' simple.txt

sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
flow = 0; rem msgbox("Flow layout?",4+32+256)=6
flags$ = iff(flow,$00190083$,$00090083$)
window! = sysgui!.addWindow(25,25,500,400,"BBjSimpleWindow",flags$)
window!.setName("BBjTopLevelWindow")
window!.setCallback(window!.ON_CLOSE,"eoj")
flags$ = iff(msgbox("Simple child window?",4+32)=6,$00008000$,$00000000$)
if flow then flags$ = ior(flags$,$00100000$)
simple! = window!.addChildWindow(101,25,25,450,300,"",flags$,1)
simple!.setName("BBjSimpleWindow")
simple!.setBackColor(BBjColor.YELLOW)
button! = simple!.addButton(1,25,25,400,25,"BBjButton",$$)
button!.setName("BBjButton")
button!.setCallback(button!.ON_BUTTON_PUSH,"click")
editbox! = simple!.addEditBox(102,25,75,400,25,"BBjEditBox",$$)
tbutton! = simple!.addToolButton(104,50,175,350,25,"BBjToolButton",$$)

rem ' adding the groupbox after the toolbutton tests the z-order settings.
groupbox! = simple!.addGroupBox(103,25,125,400,100,"BBjGroupBox",$$)
tbutton!.setCallback(tbutton!.ON_TOOL_BUTTON_PUSH,"click")
button2! = window!.addButton(2,25,350,450,25,"BBjButton",$$)
button2!.setName("BBjButton")
button2!.setCallback(button2!.ON_BUTTON_PUSH,"click")
status! = simple!.addStatusBar(99,err=*next); status!.setText("BBjStatusBar"); goto ok
i = msgbox(errmes(-1))

ok:
    process_events

eoj:
release

click:
    e! = sysgui!.getLastEvent()
    c! = e!.getControl()
    w! = c!.getParentWindow()
    simple$ = Boolean.toString(w!.isSimpleWindow())
    msg$ = c!.getName()+" "+str(w!)+" isSimpleWindow="+simple$
    i = msgbox(msg$,0,e!.getEventName())
return