BBjTopLevelWindow::isDesktopModal

Description

In BBj 23.05 and higher, this method returns whether the BBjTopLevelWindow is modal on an MDI desktop. This setting is ignored if the window isn't on an MDI desktop.

Syntax

Return Value	Method
boolean	isDesktopModal()

Parameters

None.

Return Value

Returns a boolean to indicate whether the BBjTopLevelWindow was created with the MDI Desktop Modal creation flag $02000000$.

Example

rem ' BBjTopLevelWindow::isDesktopModal

sysgui! = bbjapi().openSysGui("X0")

argv$ = argv(1,err=*next)

if (argv$ = "client1") then
    print 'hide',
    window! = sysgui!.addWindow(25,25,200,200,"Window 1",$00090083$)
    window!.addButton(1,25,25,100,25,"Click").setCallback(BBjAPI.ON_BUTTON_PUSH,"click")
    text$ = "getWindowMode = " + window!.getWindowMode() + "; "
    text$ = text$ + "isDesktopModal = " + Boolean.toString(window!.isDesktopModal())
    text! = window!.addStaticText(101,25,75,150,75,text$,$$)
    text!.setToolTipText(text$)
endif

if (argv$ = "client2") then
    print 'hide',
    window! = sysgui!.addWindow(150,150,200,200,"Desktop Modal Window 2",$020b0083$)
    window!.addButton(1,25,25,100,25,"Click").setCallback(BBjAPI.ON_BUTTON_PUSH,"click")
    text! = window!.addStaticText(101,25,75,150,75,"Close this desktop modal window to access the non-modal window",$$)
    text$ = "getWindowMode = " + window!.getWindowMode() + "; "
    text$ = text$ + "isDesktopModal = " + Boolean.toString(window!.isDesktopModal())
    text!.setToolTipText(text$)
endif

if (argv$ = "client3") then
    print 'hide',
    window! = sysgui!.addWindow(500,500,200,200,"Group Modal Window 3",$400b0083$)
    window!.addButton(1,25,25,100,25,"Click").setCallback(BBjAPI.ON_BUTTON_PUSH,"click")
    text! = window!.addStaticText(101,25,75,150,75,"Close this group modal window to access the MDI desktop",$$)
    text$ = "getWindowMode = " + window!.getWindowMode() + "; "
    text$ = text$ + "isDesktopModal = " + Boolean.toString(window!.isDesktopModal())
    text!.setToolTipText(text$)
endif

if (argv$ = "") then
    window! = bbjapi().getMDI()
    window!.createMDIWindow(200,200,800, 600,"14971",$0009000f$)
    window!.setDefaultMDIMode("MDI")
    window!.setOutlineDrag(0)
    a = scall("bbj "+pgm(-1)+" - client1 &")
    a = scall("bbj "+pgm(-1)+" - client2 &")
    a = scall("bbj "+pgm(-1)+" - client3 &")
endif

window!.setCallback(BBjAPI.ON_CLOSE,"eoj")

process_events

eoj:
release

click:
    event! = bbjapi().getSysGui().getLastEvent()
    a=msgbox(event!.getEventName())
return