BBjTabCtrl::getTabPlacement

Description

Returns the placement of the tabs in the BBjTabCtrl.

Syntax

Return Value

Method

int

getTabPlacement()

Parameters

None.

Return Value

Returns one of the following constants which is the placement of the tabs:

TOP

BOTTOM

LEFT

RIGHT

Remarks

The default tab placement is TOP.

Example

REM Get the placement of the tabs in a tab control

REM Obtain the instance of the BBjAPI object
LET myAPI!=BBJAPI()

REM Open the SysGui device
LET SYSGUI=UNT
OPEN (SYSGUI)"X0"

REM Obtain the instance of the BBjSysGui object
LET mySysGui!=myAPI!.getSysGui()

REM Set addWindow param values
LET X=10
LET Y=10
LET WIDTH=400
LET HEIGHT=400
LET TITLE$="BBj Window"

REM Create a window, initialy invisible
LET myWindow!=mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$,$00000012$)

REM Add a tab control to the window
LET myTabCtrl!=myWindow!.addTabCtrl(101,50,50,200,200)

REM Set the tabs to be multi-lined
myTabCtrl!.setMultiLine(mySysGui!.TRUE)

REM Set tab placement to RIGHT
myTabCtrl!.setTabPlacement(mySysGui!.RIGHT)

PARENT_CONTEXT = mySysGui!.getContext()

NUM_OF_TABS = 4
FOR I = 1 TO NUM_OF_TABS
   REM Create a child window
   LET myChildWindow!=myWindow!.addChildWindow(200+I,75,75,100,100,"",$$,PARENT_CONTEXT+I,$$)

   REM Add a static text control on the child window
   CHILD_TEXT$="Child Window " + STR(I)
   LET myStaticText!=myChildWindow!.addStaticText(300+I,X,Y,WIDTH,HEIGHT,CHILD_TEXT$)

   REM Add the child window as a tab on the tab control
   TAB_TEXT$="Tab " + STR(I)
   myTabCtrl!.addTab(TAB_TEXT$,myChildWindow!)
NEXT I

REM Set the top level window visible
myWindow!.setVisible(1)

REM Get the placement of the tabs in a tab control, this will return
REM the constant RIGHT
TAB_LOC = myTabCtrl!.getTabPlacement()

REM Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,0)

REM Process Events
PROCESS_EVENTS

REM Callback routine called when the user closes the application window
APP_CLOSE:
RELEASE
RETURN

See Also

BBjAPI

BBjSysGui

BBjControl

BBjWindow

See the BBj Object Diagram for an illustration of the relationship between BBj Objects.