BBjProgressBar::getMinimum

rem 'Get the minimum value of a progress bar control

rem 'Obtain the instance of the BBjAPI object
let myAPI! = BBjAPI()

rem 'Open the SysGui device
SYSGUI = UNT
OPEN (SYSGUI)"X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui! = myAPI!.getSysGui()

rem 'Set addWindow param values
X = 100
Y = 100
WIDTH = 300
HEIGHT = 100
TITLE$="BBj Window"

rem 'Set the current context
mySysGui!.setContext(0)

rem 'Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

rem 'Add some buttons to the window
startButton! = myWindow!.addButton(1,5,10,90,30,"Start")
stopButton! = myWindow!.addButton(2,105,10,90,30,"Stop",$0001$)
resetButton! = myWindow!.addButton(3,205,10,90,30,"Reset")

rem 'Add a progress bar control to the window
myProgressBar! = myWindow!.addProgressBar(101,5,50,290,30,1964,1993)

rem 'Get the minimum value of the progress bar
MIN = myProgressBar!.getMinimum()
TEMP = MSGBOX("Minimum value is "+STR(MIN))

rem 'Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())
CALLBACK(ON_BUTTON_PUSH,doStart,mySysGui!.getContext(),startButton!.getID())
CALLBACK(ON_BUTTON_PUSH,doStop,mySysGui!.getContext(),stopButton!.getID())
CALLBACK(ON_BUTTON_PUSH,doReset,mySysGui!.getContext(),resetButton!.getID())

rem 'Process Events
process_events

doStart:
    startButton!.setEnabled(0)
    myAPI!.createTimer("",0.1,"progress")
    stopButton!.setEnabled(1)
return

doStop:
    stopButton!.setEnabled(0)
    myAPI!.removeTimer("")
    startButton!.setEnabled(1)
return

progress:
    myProgressBar!.setValue(myProgressBar!.getValue()+1)
    if myProgressBar!.getValue() >= myProgressBar!.getMaximum()
        gosub doStop
    endif
return

doReset:
    myProgressBar!.setValue(myProgressBar!.getMinimum())
return

rem 'Callback routine called when the user closes the application window
APP_CLOSE:
release