BBjInputE::getError

rem 'Get the number of the last error trapped by a BBjInputE control

rem 'Obtain the instance of the BBjAPI object
let myAPI! = BBjAPI()

rem 'Open the SysGui device
SYSGUI = UNT
OPEN (SYSGUI) "X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui! = myAPI!.getSysGui()

rem 'Set addWindow param values
X = 10
Y = 10
WIDTH = 200
HEIGHT = 200
TITLE$="BBj Window"

rem 'Set the current context
mySysGui!.setContext(0)

rem 'Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$)

rem 'Add an INPUTE control that accepts only alphabetic characters and converts
rem 'all to upper case, limiting input to 10 characters, and inserting
rem 'the value "STANDARD" when the user hits the restore key (normally ESCAPE)
myInputE! = myWindow!.addInputE(101,50,100,90,30,$0804$,"AAAAAAAAAA","",1,"STANDARD","")

myInputE!.setLength(1024)
MESSAGE$="Error code for myInputE!.setLength(1024) is: "+STR(myInputE!.getError())
let X = MSGBOX(MESSAGE$)

myInputE!.setLength(2048)
MESSAGE$="Error code for myInputE!.setLength(2048) is: "+STR(myInputE!.getError())
let X = MSGBOX(MESSAGE$)

rem 'Register the CALLBACK routines
CALLBACK(ON_CLOSE,APP_CLOSE,mySysGui!.getContext())

rem 'Process Events
process_events

rem 'Callback routine called when the user closes the application window
APP_CLOSE:
release