BBjHtmlView::getUserAgent

Description

In BBj 15.0 and higher, this method returns the user agent string for this BBjHtmlView control.

Syntax

Return Value	Method
string	getUserAgent()

Parameters

None.

Return Value

Returns the user agent string for the BBjHtmlView control.

Remarks

For more information about the user agent string, go to useragentstring.com.

Example

rem ' BBjHtmlView::getUserAgent

url$ = "https://www.whatismybrowser.com/detect/what-is-my-user-agent"
if (info(3,6)="5" or info(3,6)="6") then
    url$ = "https://www.whatismybrowser.com/feature/iframe"
    url$ = "http://www.useragentstring.com/"
endif
client = 0
if (info(3,6)<>"5" and info(3,6)<>"6") then
    client = msgbox("BBjHtmlView Client",7+32+512,"BBjHtmlView","Swing","JavaFX","Chromium")
    switch client
        case 1; rem ' Swing
            print stbl("!OPTIONS","CHROMIUM_HTMLVIEW=FALSE",ERR=*NEXT)
            print stbl("!OPTIONS","JAVAFX_HTMLVIEW=FALSE",ERR=*NEXT)
            break
        case 2; rem ' JavaFX
            print stbl("!OPTIONS","CHROMIUM_HTMLVIEW=FALSE",ERR=*NEXT)
            print stbl("!OPTIONS","JAVAFX_HTMLVIEW=TRUE",ERR=*NEXT)
            break
        case 3; rem ' Chromium
            print stbl("!OPTIONS","CHROMIUM_HTMLVIEW=TRUE",ERR=*NEXT)
            print stbl("!OPTIONS","JAVAFX_HTMLVIEW=TRUE",ERR=*NEXT)
            break
    swend
endif
sysgui = unt
open (sysgui)"X0"
sysgui! = bbjapi().getSysGui()
window! = sysgui!.addWindow(50,50,800,700,"htmlview "+url$,$00090083$)
window!.setCallback(window!.ON_CLOSE,"eoj")
window!.setCallback(window!.ON_RESIZE,"resize")
getUserAgent! = window!.addButton(1,25,25,100,25,"getUserAgent",$$)
getUserAgent!.setCallback(getUserAgent!.ON_BUTTON_PUSH,"getUserAgent")
text! = window!.addEditBox(100,150,25,625,25,"",$0200$)
setUserAgent! = window!.addButton(2,25,75,100,25,"setUserAgent",$$)
setUserAgent!.setCallback(setUserAgent!.ON_BUTTON_PUSH,"setUserAgent")
edit! = window!.addEditBox(101,150,75,625,25,"",$$)
htmlview! = window!.addHtmlView(102,25,125,750,550,"",$$)
htmlview!.setUrl(url$)
process_events

eoj:
release

resize:
    event! = sysgui!.getLastEvent()
    htmlview!.setSize(event!.getWidth()-50,event!.getHeight()-150)
return

getUserAgent:
    useragent$ = htmlview!.getUserAgent()
    text!.setText(useragent$)
return

setUserAgent:
    htmlview!.setText("")
    htmlview!.setUserAgent(edit!.getText())
    htmlview!.setUrl(url$)
return