BBjFontChooser::setCancelButtonText

Description

In BBj 7.00 and higher, this method sets the text of the BBjFontChooser's [Cancel] button.

Syntax

Return Value	Method
void	setCancelButtonText(string text)

Parameters

Variable	Description
text	The new text for the [Cancel] button.

Return Value

None.

Example

rem 'Set cancel button text

rem 'Obtain the instance of the BBjAPI object
let myAPI! = BBjAPI()

rem 'Open the SysGui device
SYSGUI = UNT
OPEN (SYSGUI)"X0"

rem 'Obtain the instance of the BBjSysGui object
let mySysGui! = myAPI!.getSysGui()

rem 'Set addWindow param values
X = 100
Y = 100
WIDTH = 400
HEIGHT = 250
TITLE$="BBjFontChooser"

rem 'Create a window
myWindow! = mySysGui!.addWindow(X,Y,WIDTH,HEIGHT,TITLE$,$00010003$)

rem 'Add a font chooser on the window
myFontChooser! = myWindow!.addFontChooser(101,0,0,WIDTH,HEIGHT)

rem 'Customize the approve button text
text$ = myFontChooser!.getApproveButtonText()
myFontChooser!.setApproveButtonText("Select Font")
print "Approve selection changed from '"+text$+"' to '"+myFontChooser!.getApproveButtonText()+"'"

rem 'Customize the cancel button text
text$ = myFontChooser!.getCancelButtonText()
myFontChooser!.setCancelButtonText("Exit")
print "Cancel selection changed from '"+text$+"' to '"+myFontChooser!.getCancelButtonText()+"'"

rem 'Register the CALLBACK routines
CALLBACK(ON_FONTCHOOSER_APPROVE,APPROVE,mySysGui!.getContext(),myFontChooser!.getID())
CALLBACK(ON_FONTCHOOSER_CANCEL,CANCEL,mySysGui!.getContext(),myFontChooser!.getID())
CALLBACK(ON_RESIZE,RESIZE,mySysGui!.getContext())
CALLBACK(ON_CLOSE,CANCEL,mySysGui!.getContext())

rem 'Process Events
process_events

RESIZE:
    myFontChooser!.setSize(myWindow!.getWidth(),myWindow!.getHeight())
return

rem 'Callback routine called when the fontchooser's OK button is pressed
APPROVE:
    rem 'Display a message with the approprate font
    gosub FontInfo
    message$="<html><head><style type = 'text/css'>p{font:"+html$+"}</style></head><body><p>"+info$+"</p></body></html>"
    let X = MSGBOX(MESSAGE$,0,"Selected Font")
release

FontInfo:
    Font! = myFontChooser!.getSelectedFont()
    name$ = Font!.getName()
    style = Font!.getStyle()
    size = Font!.getSize()
    if (style = 0) then
        style$="Plain"
        html$ = str(size)+"px "+name$
    else
        style$=""
        if (fnIsBitSet(style,Font!.FONT_BOLD)) then
            style$ = style$+"Bold "
        endif
        if (fnIsBitSet(style,Font!.FONT_ITALIC)) then
            style$ = style$+"Italic "
        endif
        style$ = cvs(style$,3)
        html$ = cvs(style$,8)+" "+str(size)+"px "+name$
    endif
    info$ = name$+" "+style$+" "+str(size)
return

def fnIsBitSet(value,bit)
return sgn(dec(and(bin(value,4),bin(bit,4))))
fnend

rem 'Callback routine called when the fontchooser's Cancel button is
rem 'pressed or the window is closed without selecting a font
CANCEL:
    rem 'Display a message notifying of the cancel
    MESSAGE$="No font was chosen!"
    let X = MSGBOX(MESSAGE$)
release

BBjFontChooser::setCancelButtonText

Description

Syntax

Parameters

Return Value

Example

See Also